ANSYS Mechanical APDL Code for Delamination in Mixed Mode

Código de ansys APDL para delaminaciones en compuestos en modo mixto





/PREP7
C*** ****************************************************************
C*** PARAMETROS GEOMÉTRICOS en metros Y DEL MATERIAL, CARGA DEL ENSAYO
C*** ****************************************************************

c = 0.055394 ! Posición de la carga
L = 0.062 ! Longitud entre apoyos definida según ASTMD6671
h = 0.00504 ! un medio del espesor promedio de la probeta
b = 0.02554 ! ancho promedio de la probeta
a = 0.02554 ! tamaño grieta

dbisagra = 0.03 ! distancia bisagra al borde
LT = 0.163 ! Longitud total de la probeta

TMALLA = 0.0005 ! Tamaño de malla

E = 5.969e9 ! Módulo de elasticidad
nu = 0.3095 ! razón de Poisson

UCARGA=-0.01748 ! DESPLAZAMIENTO CARGA EN M

g1c=910                   !* critical energy-release rate
g2c=3828
g3c=0 ! ignora modo III de falla
n1=0.6763 ! exponente del modo I
n2=0.8468 ! exponente del modo II
n3=1 ! exponente del modo III

PASOS=20 ! número de pasos de cálculo
C*** ****************************************************************

ET,1,PLANE182  
KEYOPT,1,1,0
KEYOPT,1,3,3 ! plane strain con espesor
KEYOPT,1,6,0
R,1,b,

et,3,202                   !* 2d 4-node cohesive zone element
keyopt,3,3,3               !* plane strain
R,2,b,
 
MPTEMP,,,,,,,,
MPTEMP,1,0
MPDATA,EX,1,,E
MPDATA,PRXY,1,,nu

K,1000,,,,
K,2000,a+dbisagra,,,
K,1,0,h,,
K,2,dbisagra,h,,
K,3,dbisagra+L,h,,
K,4,dbisagra+2*L,h,,
K,5,LT,h,,
K,6,LT,,,


 

A,1000,2000,6,5,4,3,2,1

TYPE,   1  
MAT,       1
REAL,  
ESYS,       0  
SECNUM,
!*
ARSYM,Y,1
ESIZE,TMALLA,0,

ALLSEL,ALL
AMESH,ALL



 
NSEL,S,LOC,X,A+DBISAGRA,LT
NUMMRG,NODE
esln
czmesh,,,1,y,0
ALLSEL,ALL

KSEL,S,LOC,X,A+DBISAGRA,LT
NUMMRG,KP
ALLSEL,ALL

esel,s,ename,,202          !* elementos de interface tipo 202
cm,cpath,elem              !* define componente de elementos por el que va a delaminar: crack-growth path



C*** *************************************************************************
C*** definición del componente de punta de grieta y criterio de fratura
C*** *************************************************************************
KSEL,S, , ,8
NSLK,S,
CM,cracktip,NODE !Define el componente de nodos de grieta
*GET,NODOGRIETA,NODE,,NUM,MIN
ALLSEL,ALL


tb,cgcr,1,,,powerlaw        !* añade el criterio de fratura al material
tbdata,1,g1c,g2c,g3c,n1,n2,n3

CINT,NEW,1 ! CALCULO DE LA TASA DE LIBERACIÓN DE ENERGÍA G
CINT,TYPE,VCCT
CINT,SYMM,OFF
CINT,CTNC,cracktip


C*** **************************************************************************
C*** definición de las cargas
C*** **************************************************************************
DK,13, , , ,0,ALL, , , , , ,
DK,11, , , ,0,UY, , , , , ,

KSEL,S, , ,3
NSLK,S,
*GET,NODOAPOYO,NODE,,NUM,MIN
allsel,all

KSEL,S, , ,11
NSLK,S,
*GET,NODOAPOYO1,NODE,,NUM,MIN
allsel,all

KSEL,S, , ,2
NSLK,S,
*GET,NODOBISAGRA,NODE,,NUM,MIN
allsel,all

KSEL,S, , ,13
NSLK,S,
*GET,NODOBISAGRA1,NODE,,NUM,MIN
allsel,all
U1CARGA=UCARGA/PASOS
CE,1,U1CARGA,NODOBISAGRA,UY,-c/L,NODOAPOYO,UY,(L+c)/L

C*******************************************************************
FINISH
DELTAT=1/PASOS
/SOLU
! crack-growth simulation set
cgrow,new,1          !* crack-growth set
cgrow,cid,1          !* cint id for vcct calculation
cgrow,cpath,cpath    !* crack path
cgrow,fcopion,mtab,1    !* fracture criterion, permite usar un criterio diferente de Gt max
cgrow,dtime,2e-3
cgrow,dtmin,2e-3
cgrow,dtmax,2e-3
cgrow,fcrat,1 ! maximo valor de f antes de propagar>=1


*DO,K,1,PASOS,1
time,DELTAT*K
U1CARGA=UCARGA/PASOS*K
CECMOD,1,U1CARGA
nsubst,10,30,5 ! define número de iteraciones
allsel,all
outres,all,all
SOLVE
*ENDDO

FINISH



/post26
NUMVAR,20
nsol,2,NODOBISAGRA,u,y,UY1
nsol,3,NODOAPOYO,u,y,UY2
ADD,4,2,2,3,UYCARGA,,,-1,(L+c)/L,-(L+c)/L


rforce,5,NODOAPOYO1,F,y,REACCION1
rforce,6,NODOBISAGRA1,F,y,REACCION2
ADD,7,5,6,0,CARGA,,,,,

CISOL,8,1,NODOGRIETA,,G1
VARNAM,8,GI
CISOL,9,1,NODOGRIETA,,G2
VARNAM,9,GII
CISOL,10,1,NODOGRIETA,,CEXT
INT1, 20, 10, 1, ,LONGRIETA, ,,,PASOS,a !LONGITUD DE LA GRIETA
CISOL,11,1,NODOGRIETA,,GT
VARNAM,11,GTOTAL
QUOT,12,8,9,,GIGII, !RAZÓN GI/GII
QUOT,13,9,11,,GIIGT, !RAZON GII/GT
finish